Безумно полезные компоненты и классы. Которые облегчают жизнь flash-разработчикам, которые часто имеют дело с пользовательским интерфейсом как таковым (там и Tree и TabBar и MenuBar и куча всего полезного).

Советую обратить внимание на очень полезные компоненты BoxPane (и его потомки), с их помощью очень удобно создавать различного рода тянущиеся диалоги и другие элементы интерфейса (я уже написал базовый класс для диалога и с удовольствием поделюсь им в последующих постах).

Если у вас проблемы с английским языком (хотя я сомневаюсь что у флеш-девелоперов существует такая проблема), то могу перевести на русский язык описание и мануал.

Большенство записей которые удалось найти советовали использовать конструкцию:

[Embed(source='/assets/fonts/font.ttf', fontFamily="MegaFont"]

Но спешу огорчить тех кто искал ответ на вопрос «Как все-таки может заработать эта конструкция в CS3″ — никак. К сожалению в CS3 есть много вещей которые сделаны не совсем удобно для программиста (хотя во Flex реализована именно такая система внедрения, и непонятно что мешало её реализовать в CS3).

Немножко помучавшись я нашел два выхода из ситуации, но все таки избежать использования IDE нам не удастся.

Первый шаг для обоих методов одинаковый — в IDE импортировать необходимый нам шрифт, делается это таким образом:

В библиотеке (Library) жмем сюда (помечено красным):

Далее выбираем в меню пункт «New Font», и в появившемся окне выбираем необходимый шрифт и его параметры (bold, italic, bitmap, size), в поле Name вписываем идентификатор по которому мы в дальнейшем мы будем определять шрифт.

Нажимаем «OK». В библиотеке у нас появился внедренный шрифт с именем fontArial.

Далее выбираем его в списке кликаем правой кнопкой и в меню выбираем «Linkage«, в появившемся окне ставим галочки: Export for ActionScript и если необходимо Export in first frame (для экпорта класса на первый кадр, если у вас предусмотрен прелоадер и сделан он отдельно).

Нажимаем «ОК».

Второй шаг (первый способ).

Для того чтобы установить для TextField’a шрифт который мы внедрили можно прибегнуть к такой конструкции:

var _font : Font = new fontArial();
var textFormat : TextFormat = new TextFormat (_font.fontName, 14, 0x000000);
var textField : TextField = new TextField();
textField.setTextFormat (textFormat);

Лично мне такой способ не по душе, я использую среду разработки FDT, и чтобы среда разработки поняла такую запись и не ругалась на неизвестный класс fontArial (так как он импортируется в проект fla), необходимо экспортировать при публикации проекта SWC-библиотеку, а уже потом импортировать её в FDT (в общем способ не из лучших).

Поэтому я использую другой способ по количеству кода он превосходит предыдущий вариант, но на мой взгляд гораздо удобнее в использовании:
Второй шаг (второй способ ):

Для начала я должен рассказать вам о функции getDefinitionByName(), на случай если вы не знаете что она делает.

Функция getDefinitionByName() преобразует имя класса в ссылку на класс, то есть использование конструкции:

var SpriteClass : Class = getDefinitionByName ("Sprite") as Class;

приводит к тому что SpriteClass становится ссылкой на класс Sprite и вы можете создавать спрайты используя данную ссылку:

var mySprite1 : Sprite = new SpriteClass() as Sprite;

И так переходим к делу.

Чтобы организовать для каждого необходимого проекта импорт шрифтов необходимых только данному проекту мы должны написать абстрактный класс:

package fonts {
	import flash.text.Font;
	import flash.utils.getDefinitionByName;		
	/**
	 * @author mayak
	 */
	public class AbstractFontManager {
		protected static function loadFont(fontId : String) : String {
			try {
				var fontClass : Class = getDefinitionByName(fontId) as Class;
				var font : Font = new fontClass() as Font;
				Font.registerFont(fontClass);
				trace ('ok');
			}
			catch (e : Error) {
				trace("Font " + fontId + " can not be loaded, check linkage\n" + e.toString());
			}
			return font.fontName;
		} 
	}
}

Следующим функция loadFont берет ссылку на класс необходимого нам шрифта и регистриурет данный шрифт, возвращая имя шрифта (а не линковки)

И во второй части шага мы напишем свой собственный класс для определенного проекта:

package fonts {
    import fonts.AbstractFontManager;

    /**
     * @author mayak
     */
    public class FontManager extends AbstractFontManager {
        public static var fontNameArial : String;
        public static var fontNameTahoma : String;

        public static function initialize() : void{
            fontNameArial = loadFont ("fontArial");            
            fontNameTahoma = loadFont ("fontTahoma");
        }
    }
}

И теперь все что нам остается это использовать при создании TextFormat’a имя шрифта из FontManager’а, например FontManager.fontNameTahoma.

			var textFieldTahoma : TextField = new TextField();
			with (textFieldTahoma) {
				x=100;
				y=140;
				width=200;
				height=44;
				embedFonts = true;
				antiAliasType = "advanced";
				text = "Tahoma";
				setTextFormat(new TextFormat (FontManager.fontNameTahoma,40,0x888800));
			}

			this.addChild(textFieldTahoma);